home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1990: Discy Business / Discy Business.2mg / DEV.CD / GUIDED.TOURS / IIC.PLUS.TOUR / INSIDE.STORY / INSIDE.STORY.H (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1988-04-11  |  4.1 KB  |  108 lines  |  [FC] Applesoft BASIC Program (0x0801)
  1. 4  ONERR  GOTO 10000
  2. 5  HCOLOR= 3:D$ =  CHR$(4):KS% =  -16384:KC% =  -16368:HPG% = 2000:MOVE = 4096:FT = 4113:F1 = 17:F2 = 20
  3. 10  GOSUB 155: PRINT D$"open text2": PRINT D$"read text2": PRINT D$: PRINT D$"bload p.notitle,a$4000": GOSUB 120: GOTO 1000
  4. 20  FOR Z = 0 TO 200
  5. 22  IF  PEEK(KS%) <128  THEN  NEXT Z
  6. 23  IF  PEEK(KS%) < >141  AND  PEEK(KS%) < >155  AND Z <201  THEN  POKE KC%,0: GOTO 22
  7. 24  RETURN 
  8. 30  FOR Z = 0 TO 70: NEXT Z: RETURN 
  9. 40  FOR I = 0 TO 3: GOSUB 251: GOSUB 30: GOSUB 250: GOSUB 30: NEXT I: RETURN 
  10. 100  HTAB (W% - LEN(S$) +3)/2: PRINT S$;: RETURN 
  11. 110 D$ =  CHR$(4):TMP$ = S$: IF TC% <LM%  THEN  RETURN 
  12. 111  POKE KC%,0
  13. 112  FOR CT = 0 TO 1000
  14. 113  IF  PEEK(KS%) <128  AND CT <1001  THEN  NEXT CT
  15. 114  IF  PEEK(KS%) = 141  THEN  POKE KC%,0: VTAB T% +1: PRINT :S$ = TMP$: RETURN 
  16. 115  IF  PEEK(KS%) = 155  THEN  POKE KC%,0: PRINT D$"CLOSE": GOTO 9990
  17. 116 CT = 1001
  18. 118  VTAB 24: HTAB 15: PRINT "Press RETURN";: GOSUB 20: HTAB 15: PRINT "            ";: GOSUB 20: VTAB 19: GOTO 114
  19. 120  POKE 4013,32: POKE 4017,64: CALL 4000: RETURN 
  20. 130  POKE 4013,64: POKE 4017,32: CALL 4000: RETURN 
  21. 140  GOSUB 155: PRINT D$"READ TEXT2"
  22. 142  INPUT "";TX$: IF  LEFT$(TX$,1) = "^"  THEN 148
  23. 144  IF  LEN(TX$) >39  THEN  PRINT  LEFT$(TX$,40);: GOTO 142
  24. 146  PRINT TX$: GOTO 142
  25. 148  PRINT D$:TC% = TC% +1: RETURN 
  26. 150  POKE 32,L%: POKE 33,W%: POKE 34,T%: POKE 35,B%: RETURN 
  27. 152 L% = 0:W% = 40:T% = 0:B% = 24: GOSUB 150: RETURN 
  28. 155 L% = 0:W% = 40:T% = 19:B% = 24: GOSUB 150: VTAB 19: PRINT  CHR$(12): HOME : RETURN 
  29. 160 A1% =  VAL( LEFT$(V$,3)):B1% =  VAL( MID$ (V$,5,3)):C1% =  VAL( RIGHT$(V$,3))
  30. 162 S% = 1: IF A1% >B1%  THEN S% =  -1
  31. 165  RETURN 
  32. 170  GOSUB 160: FOR V = A1% TO B1%  STEP S%: HPLOT C1%,V: NEXT V: RETURN 
  33. 180  GOSUB 160: FOR H = A1% TO B1%  STEP S%: HPLOT H,C1%: NEXT H: RETURN 
  34. 200  POKE 32,L% -1: POKE 33,W% +2: POKE 34,T% -1: POKE 35,B% +1:L1% = L% *7:R1% = (L% +W%) *7:T1% = T% *8:B1% = B% *8:XC% = L1% +(R1% -L1%)/2:YC% = T1% +(B1% -T1%)/2:I1% = (R1% -XC%)/5:I2% = (B1% -YC%)/5
  35. 210  FOR I = 1 TO 5:DX% = I *I1%:DY% = I *I2%: HPLOT XC% -DX%,YC% -DY% TO XC% +DX%,YC% -DY% TO XC% +DX%,YC% +DY% TO XC% -DX%,YC% +DY% TO XC% -DX%,YC% -DY%: NEXT I
  36. 220  VTAB T%: HTAB L%: PRINT  CHR$(12):: FOR I = 2 TO 4  STEP 2: HPLOT L1% -I,T1% -I TO R1% +I,T1% -I TO R1% +I,B1% +I TO L1% -I,B1% +I TO L1% -I,T1% -I: NEXT I: GOSUB 150: VTAB T%: HOME 
  37. 230  RETURN 
  38. 250  INVERSE : GOTO 255
  39. 251  NORMAL 
  40. 255  GOSUB 152: VTAB  VAL( LEFT$(S$,2)): HTAB  VAL( MID$ (S$,3,2)): PRINT  RIGHT$(S$, LEN(S$) -4): NORMAL : RETURN 
  41. 300  POKE FT,F2: CALL MOVE: GOSUB 140: GOSUB 110: RETURN 
  42. 310  POKE FT,F1: CALL MOVE: GOSUB 140: GOSUB 110: RETURN 
  43. 990  HOME : POKE 33,33: END 
  44. 1000  & : REM * Turn on HIRES *
  45. 1010  GOSUB 300
  46. 1020  PRINT D$"bload p.cover,a$4000": GOSUB 120: GOSUB 140: GOSUB 110
  47. 1100  PRINT D$"bload p.chels2,a$4000": GOSUB 120: GOSUB 140: GOSUB 110
  48. 1110  GOSUB 310: GOSUB 300: GOSUB 310
  49. 1115  POKE FT,F2: CALL MOVE
  50. 1120  GOSUB 155:S$ = "1823DISK DRIVE": GOSUB 40: GOSUB 140: GOSUB 110
  51. 1140  GOSUB 251: GOSUB 155
  52. 1150  FOR I = 0 TO 30:C = 3 *((I/2) < > INT(I/2)): HCOLOR= C: HPLOT 128,22 TO 128,5 TO 8,5 TO 8,145 TO 128,145 TO 128,116: NEXT I
  53. 1155  GOSUB 140: GOSUB 110: GOSUB 155
  54. 1160 S$ = "1203MICROPROCESSOR": GOSUB 40: GOSUB 140: GOSUB 110
  55. 1168  GOSUB 251: GOSUB 155
  56. 1170 S$ = "1709 ROM ": GOSUB 40: GOSUB 140: GOSUB 110
  57. 1175  GOSUB 140: GOSUB 110: GOSUB 310: GOSUB 300
  58. 1178  GOSUB 251: GOSUB 155
  59. 1200  GOSUB 155:S$ = "0407 RAM ": GOSUB 40: GOSUB 140: GOSUB 110
  60. 1210  GOSUB 310: GOSUB 300
  61. 1390  GOSUB 155: GOSUB 130
  62. 1400  HCOLOR= 3
  63. 1410  GOSUB 140
  64. 1420 L% = 5:W% = 25:T% = 4:B% = 16: GOSUB 200
  65. 1422  HPLOT 55,55 TO 50,61 TO 50,86 TO 55,80 TO 50,86 TO 106,86 TO 112,80 TO 112,55 TO 55,55 TO 55,80 TO 112,80
  66. 1423  FOR H = 60 TO 102  STEP 6: HPLOT H -1,88 TO H -1,84 TO H,84 TO H,84 TO H,88 TO H -5,93: HPLOT H,55 TO H,51 TO H -4,55: NEXT H
  67. 1425 S$ = "1410 RAM ": GOSUB 251:S$ = "1425POWER": GOSUB 251
  68. 1430  HPLOT 167,76 TO 167,88 TO 203,88 TO 203,76 TO 167,76: HPLOT 187,76 TO 183,76 TO 183,70 TO 112,70 TO 112,66 TO 187,66 TO 187,76
  69. 1432 S$(0) = "1125 OFF ":S$(1) = "1125  ON ":S$(2) = "0809        ":S$(3) = "0909  INFO  ":S$(4) = "1009        ":S$(5) = "0909        "
  70. 1433  FOR I = 1 TO 3: GOSUB 20: NEXT I
  71. 1435  FOR N = 0 TO 1: HCOLOR= 0:OFF% = 1: IF N/2 =  INT(N/2)  THEN  HCOLOR= 3:OFF% = 0
  72. 1440  IF OFF%  THEN S$ = S$(0): GOSUB 251: GOTO 1450
  73. 1445 S$ = S$(1): GOSUB 250
  74. 1450  FOR V = 79 TO 77  STEP  -1: HPLOT 168,V TO 202,V: NEXT V: FOR V = 76 TO 67  STEP  -1: HPLOT 184,V TO 186,V: NEXT V: FOR H = 184 TO 113  STEP  -1: HPLOT H,67 TO H,69: NEXT H
  75. 1460  FOR J = 2 TO 4:S$ = S$(J): IF   NOT (OFF%)  THEN  GOSUB 250: GOTO 1470
  76. 1465  IF J = 3  THEN S$ = S$(5)
  77. 1466  GOSUB 251
  78. 1470  NEXT J
  79. 1480  IF N = 1  THEN  GOSUB 20
  80. 1485  IF N = 0  THEN  GOSUB 110: GOSUB 140: GOSUB 20: POKE KC%,0
  81. 1490  NEXT N: GOSUB 110: GOSUB 120
  82. 1495 S$ = "0407 RAM ": GOSUB 251: GOSUB 155
  83. 1500  FOR I = 1 TO 2: GOSUB 310: GOSUB 300: NEXT I
  84. 9900  GOSUB 140: POKE 793,1: GOSUB 110
  85. 9980  GOSUB 152: HOME : PRINT D$"CLOSE": TEXT : VTAB 12:S$ = "Just a moment please...": GOSUB 100: PRINT : PRINT D$"-INSIDE.STORY.S": END 
  86. 9990  GOSUB 152: HOME : TEXT : VTAB 12:S$ = "Just a moment please....": GOSUB 100: PRINT : PRINT  CHR$(4)"-MENU"
  87. 10000 ERR% =  PEEK(222):LINE% =  PEEK(218) + PEEK(219) *256
  88. 10001  IF ERR% = 255  THEN  RESUME 
  89. 10010  GOSUB 152: HOME : PRINT CL$: TEXT : HOME : PRINT D$"CLOSE": VTAB 5: PRINT "An ERROR has occurred in this program.": PRINT 
  90. 10100  IF ERR% < >6  THEN 10200
  91. 10105  IF LINE% < >9980  THEN 10210
  92. 10110  PRINT "The next program to be executed was not": PRINT "found on the diskette in the drive.": GOTO 10220
  93. 10200  IF ERR% < >8  THEN 10900
  94. 10210  PRINT "There appears to be a problem with the": PRINT "diskette in the built in disk drive."
  95. 10220  PRINT : PRINT "Make sure you have the correct diskette": PRINT "(Your Tour of the Apple II) in the disk": PRINT "drive.": GOTO 11000
  96. 10900  PRINT "The error does not seem to be one that": PRINT "this program knows about.  Please note": PRINT "the error number and line number listed": PRINT "below and report it to your dealer."
  97. 10910  PRINT : PRINT "Error Number = "ERR%: PRINT "Line Number  = "LINE%
  98. 10920  PRINT : PRINT "Please put another program diskette in": PRINT "the disk drive.  When you have done": PRINT "this press RETURN to continue."
  99. 10930  GOSUB 110: PRINT : PRINT D$"PR#5"
  100. 11000  PRINT : PRINT "Press RETURN to continue."
  101. 11010  IF  PEEK(KS%) < >141  THEN 11010
  102. 11020  POKE (KC%),0:EC% = EC% +1: IF EC% >2  THEN 11900
  103. 11030  IF LINE% = 9990  THEN 9990
  104. 11040  IF LINE% = 9980  THEN 9980
  105. 11050  IF ERR% = 8  OR ERR% = 6  THEN  RUN 
  106. 11900  HOME : GOTO 10900
  107. 32998  REM <CTRL-0x0a><CTRL-0x0a>* BY: LANCE G. SALEME
  108. 32999  REM * COPYRIGHT 1984, 1986, 1988 APPLE COMPUTER, INC. *